Ce fichier est un “dump mémoire” du jeu, il n'est pas compressé ni crypté; on y retrouve la meme structure que dans le code source.

Le fichier est composé de 3 “blocs” de données:

• 1 block de 32 Kb (0x8000 bytes) avec la carte en cours
• 1 block de 2560 bytes (0x1010 bytes) contenant les unités/batiments des 2 factions
• 1 block de 5 bytes (0x0005 bytes) contenant principalement les timers du jeu.

une sauvegarde fait donc TOUJOURS 36885 bytes

Dans le code source, la sauvegarde se fait uniquement dans le fichier SAVEGAME.DAT.

Game_WriteSaveGame:
		MOV	AH,0x3c				; bug no mod selected : random ?
		MOV	CX,0x0
		MOV	DX,fname_SaveGame_DAT		; = "SAVEGAME.DAT"
		MOV	AH,0x3c
		INT	0x21				; Create/truncate file
		JC	exitError			; exit function without handling
		MOV	[fhandler_SaveGame],AX		; preserve file handler
	   	JMP	continue
exitError:	RET

On découvre ici que cette fonction ne gère aucune erreur, la sauvegarde est simplement abandonnée en cas d'erreur d'ouverture de fichier.

L'usage du JMP pour sauter au dessus du RET d'erreur ressemble beaucoup à une structure de gestion d'erreurs (qui a été éliminée de la version finale) propre aux processeurs sans caches (8088, 8086, 6502, etc).

Personnellement, je n'aurais pas rompu le flux avec un JMP j'aurais placé la gestion (ou non) des erreurs à la fin de la fonction, et réservé le saut (rupture de flux) aux erreurs, afin de ne pas forcer un “flush cache” sur des processeurs plus puissant (x386 et suivant).

continue:	MOV	BX,word ptr [fhandler_SaveGame]	; fhandler
 
		; save current game map
		MOV	DX,0x0
		MOV	CX,0x8000			; 0x8000 = 256*128 
		MOV	AH,0x40
		PUSH	DS				; switch to map's Segment
		MOV	DS,word ptr [g_Seg_GameMap]
		INT	0x21				; write map (32kb)
		POP	DS				; restore DS

la carte du jeu est sauvegardée “tel quel” sans aucune encryption ni compression.

		; save unit/building records
		MOV	BX,word ptr [fhandler_SaveGame]
		MOV	DX,Game_UnitsArr_Type
		MOV	CX,0x1010			; Write 256 units/buildings (10 attributes)
		MOV	AH,0x40
		INT	0x21

Pareil pour la structure des unités/batiments, sauvegardée “tel quel” sans aucune encryption ni compression.

		; save Ingame timers
		MOV	BX,word ptr [fhandler_SaveGame]
		MOV	DX,Timer_InGame_Counter
		MOV	CX,0x5				; 1 word (total seconds) + 3 bytes (Hours:minutes:seconds)
		MOV	AH,0x40
		INT	0x21

Avant de fermer le fichier, Planet X3 sauvegarde le compteur de temps générale (1 mot) et le temps “en jeu” 3 bytes

		MOV	AH,0x3e				; close file
		MOV	BX,word ptr [fhandler_SaveGame]
		INT	0x21
		RET	

Pour n'importe quel sous-block de 0x100 bytes est divisé en 2 sous sections, 1 pour les humains (offset 0x0000), 1 pour l'ordinateur (offset 0x0080).

Suivant le code, le nombre maximum d'unités mobiles humaine diffère.

• Dans 2 fonctions, PX3 vérifie le status (offset 0x0000) pour les indices de 0 à 20 (0x00-0x14)
• Dans 1 fonction, PX3 vérifie le status (offset 0x0000) pour les indices de 20 à 50 (0x14-0x32)
• Dans 5 fonctions, PX3 vérifie le status (offset 0x0000) pour les indices de 0 à 64 (0x00-0x40)
• Dans 2 fonctions, PX3 vérifie le status (offset 0x0000) pour les indices de 20 à 64 (0x14-0x40)